Home of Wormy

Info TI Calcs Productions Community :-)

CLAUSTRO

Claustro's one of the smallest playable games available for the TI-86. It's very simple: just up and down your way through a tunnel; good to play in a few lost minutes. The game itself is just 104 bytes, so it can even be typed in manually for those who don't have a link cable. The deluxe version of 188 bytes has the following additional features:

• Increasing difficulty over time.
• Saves hiscore.
• Pause and exit keys.

Everything's included in this download:

SOURCE

init:
	cal _clrLCD
	ld  bc,$100D ;b=tunnel_pos
	             ;c=tunnel_width (<$10)
	ld  hl,$FE0E ;hl=you_pos

mainloop:
	halt
	halt

checkme:
	bit 7,(hl)
	ret nz
	psh hl
drawme:	ld  a,(hl)
	or  %1000000
	ld  (hl),a

newwalls:
	ld  a,h
	and %1
	jr  z,newdir
	dec b ;*1=down
	jr  z,newdir
	dec b ;>0--
newdir:	ld  a,b
	add a,c
	cp  63
	jr  nc,newok
	inc b ;<60++
newok:

go: ;move right
	ld  hl,$FFFF
goloop:	srl (hl)
	jr  nc,gonext
	inc hl
	set 7,(hl)
	dec hl
gonext:	dec hl
	ld  a,h
	cp  $FB
	jr  nz,goloop

tunnew: ;scroll -> a=0
	psh bc
	ld  de,16
	ld  hl,$FC00
	xor a
tuntop:	ld  (hl),-1
	add hl,de
	dnz tuntop
	ld  b,c
tunway:	ld  (hl),a
	add hl,de
	dnz tunway
tunbot:	ld  (hl),-1
	add hl,de
	cp  h ;hl>$FFFF?
	jr  nz,tunbot
	pop bc

	pop hl
inkeys:
	ld  a,%11111110
	out (1),a
	in  a,(1)
	rra ;down
	jr  nc,movedn
	bit 2,a ;up
	jr  nz,mainloop
moveup:	or  a
	sbc hl,de
	ld  a,h
	cp  $FB
	jr  nz,mainloop
movedn:	add hl,de
	jr  c,moveup
	jr  mainloop